Generalidades de plot

Hay varias formas de contruir una función

>	f :=(x) -> x*sin(x);

y se grafica

>	plot(f(x), x = -99..99);

nótese el juego con los botones de arriba.

Igual se puede graficar la función directamente y seleccionar una visión particular

>	plot(x*sin(x), x = -10..10, y=0..4);

La Sintaxis

La sintaxis del comando plot es la siguiente

plot(funcion-datos, horiz, vert, opciones)

All but the first argument are optional, but arguments must be given in the order shown above.

funcion-datos: expresión, mapping, lista o conjunto de datos a graficar

horiz / vert:

variable: etiquetas y ejes

rang0: determina el rango de graficación

variable = rango: ambos

opciones: ecuaciones de la forma  opción = VALOR

Para encontrar la lista de opciones se busca ?plot[options]

Warning, inserted missing semicolon at end of statement, ...rt, opciones);

Error, (in plot) invalid arguments

Ejemplos, escalas y etiquetas

>	plot(tan(x), x=-Pi..Pi);

la escala vertical afecta la visión, para restringir la escala podemos proceder

>	plot(tan(x), x=-Pi..Pi, `tan(x)`=-5..5);  # notese el entrecomillado inverso, ` `, para el eje vertical

Las comillas inversas `, se utilizan para encerrar textos que quisiéramos que se desplieguen en la gráfica.

nótese el símbolo de # que inhibe cualquier comando que lo siga.

Adicionalmente, vemos que las líneas verticales son espúrias. Para ello le podemos indicar al comando plot que la

función es discontínua

>	plot(tan(x), x=-Pi..Pi, `tan(x)`=-5..5,discont=true,xtickmarks=[-3.14=`-Pi`,-1.57=`-Pi/2`,1.57=`Pi/2`,3.14=`Pi`]);

Incluimos en este comando, una manera más intuitiva de ver el eje x. En el eje y, las etiquetas se puenden voltear y el título de la grafica se puede colocar, si nos ponemos un poco más exquisitos.

>	plot(tan(x), x=-Pi..Pi, `tan(x)`=-5..5,discont=true,xtickmarks=[-3.14=`-Pi`,-1.57=`-Pi/2`,1.57=`Pi/2`,3.14=`Pi`], labels=[`x`,`tan(x)`],title=`tan(x) vs x`,labeldirections = [horizontal, vertical]);

Adicionalmente, también podemos explorar la función

>	g:=(x)->sin(x^2)/x^2;

>	plot(g(x),x=-2*Pi..2*Pi);

y notamos que los ejes no tienen la misma escala, por lo cual nuestra intuición se puede ver traicionada, entonces a veces

es bueno colocar scaling=constrained

>	plot(g(x),x=-2*Pi..2*Pi, `sin(x^2)/x^2.`=-0.5..1.5, xtickmarks=[-6.28=`-2Pi`,-4.71=`-3Pi/2`,-3.14=`-Pi`,-1.57=`-Pi/2`,                                   1.57=`Pi/2`,3.14=`Pi`,4.71=`3Pi/2`,6.28=`2Pi`],scaling=constrained);

Algunas veces las funciones son razonables y no evolucionan muy rápido

>	plot(g(x),x=-infinity..infinity, `sin(x^2)/x^2.`=-0.5..1.5, scaling=constrained);

Asignación y manipulación de gráficas

Las gráficas se pueden asignar a variables para luego almacenarlas, imprimirlas o mostrarlas en pantalla. En ese caso para no ser testigo de la asignación de un inmenso y casi inenteligible conjunto de números, debemos terminar la asignación con dos punto :

>	graftan:=plot(tan(x), x=-Pi..Pi, `tan(x)`=-5..5,discont=true,xtickmarks=[-3.14=`-Pi`,-1.57=`-Pi/2`,1.57=`Pi/2`,3.14=`Pi`]):

luego podremos mostrar la gráfrica con solo invocar la varible

>

graftan;

Podemos almacenar la gráfica para utilizarla en este u otra de maple

>	save graftan, "c:/Luisn/Latex/cursos/visualizacion/graftan.m":

Nótese la forma de escribir el trayecto para almacenar el archivo y que el nombre del archivo debe tener la extensión .m para que MAPLE escriba el nombre de la variable y su asiganción en el formato interno de MAPLE. De esta forma el archivo es recuperable y se puede incluir en cualquier otra hoja de trabajo.

>	graftan := NULL: # con esta expresion "aNULLamos" el valor de la variable para luego asignarle otro graftan; read "c:/Luisn/Latex/cursos/visualizacion/graftan.m": graftan;

Como el archivo graftan.m contiene el nombre de la variable y su asignación, nos vimos abligados a "limpiar" el contenido de la variable antes de leerla del archivo donde fue almacenada. Esta acción no será necesaria si leemos esta gráfica desde otra hoja de trabajo MAPLE.

Tipos de Datos, listas, conjuntos .....y  ¿ qué más

La visualización de los datos simpre impone conocer algo de la estructura con la cual estamos trabajando. Conocer los datos Y su estructura es vital para su representación gráfica. Exploraremos aquí algunas particularidades de la representación de datos utilizando esta herramienta. MAPLE dispone de diversas maneras de representar los datos. Veamos el siguiente ejemplo con el comando solve(eqn, var) que implica resolver una ecuación algebráica, eqn, para una de las variables involucradas var

>	polinomio:=x^4-1; # shif + enter nos deja dentro del mismo grupo de comandos solve(polinomio, x);

MAPLE nos devuelve una secuencia de soluciones. Ahora bien, si procedemos a especificar UNA de las soluciones, tendríamos que

>	solve(polinomio, x)[1];

>	argumento:=polinonimo,x;

>	whattype(argumento);

claramente es una expresion de una secuencia !

Primeramente, diremos que utilizaremos de manera indistinta la palabra dato abstracto u objeto. En segundo lugar puntualizaremos que indicaremos estos objetos de distinto modo: mediante series de objetos separados por comas entre paréntisis (), objetos separados por comas entre llaves {} u objetos separados por comas entre corchetes []. Cada uno de estos conjuntos de objetos representa una estructura de datos distinta y tendrá una representación, utilización y un álgebra distinta. Nótese que ya hemos utilizado algunas de estas estructuras. Además de los argumentos de las funciones (objetos separados por comas dentro de paréntesis) en el caso de las etiquetas (labels=[,])

Consideraremos las siguientes estructuras de datos para graficar

Secuencias: Es el conjunto de datos u objetos separados por comas. Los argumentos de las funciones en MAPLE son, de acuerdo con esta definición, secuencias.

Conjuntos: Recuerda a la estructura y operación de los conjuntos matemáticos: es un conjunto de elementos separados por comas y encerrados entre llaves en los cuales los elementos aparecen un única vez y el orden de los elementos no importa. Pudiera decirse que un conjunto es una secuencia entre llaves.

Listas: Si un conjunto era una secuencia encerrada entre llaves, diremos ahora que una lista es un conjunto de conjuntos separados por comas encerrados entre corchetes, pero tambien es una secuencia encerrada entre llaves. A diferencia de los conjuntos el orden (y la posición) en el cual aparecen los elementos de la lista DEFINITIVAMENTE SI importa. Además los elementos pueden aparecer repetidos.

Arreglos: Este tipo de estructura de datos corresponde con la representación de vectores y matrices y en el caso de visualización utilizaremos las matrices para graficar archivos de datos experimentales

Tabla: La mencionamos por completitud, pero no abundaremos en su significado y uso, sólo diremos que es una estructura similar a la de registro (record) en lenguajes como Pascal o C.

Así, podemos ejemplificar lo anteriormente expuesto

>	ecua1:=3*x +4*y=5; ecua2:=8*x -y=16; solve( {ecua1, ecua2}, {x, y});

constituye el conjunto de soluciones, el cual, obviamente es equivalente a  

>	solve( {ecua2, ecua1}, {y, x});

y en contraposición al ejemplo anterior, si invertimos el orden de una lista, el resultado es otro

>	plot(x*sin(x),x =-10..10,labels=[`f(x)`,`x`],title=`f(x) vs x`);

Finalmente, podremos representar un vector como

>	v:=array( [1+a,3+2*a +b,8+3*a+5*b+8*c]);

y verificarlo

>	type(v,list);

>	type(v,vector);

>	type(v,array);

una matriz

>	M:=array([ [1-p,2-q],[2-p*q,3-p^q] ]);

Un mínimo de Operaciones con la estructura de datos

Paramétricas

Típicamente hemos visto curvas f(x) vs x y hemos graficado varias curvas en una misma gráfica f(t) vs t y g(t) vs t . Con ello lo que queremos decir es que graficamos el lugar geométrico tal que (x = t, y=f(t)) y ( x = t, y=g(t)) Ahora la idea es graficar ambas curvas etiquetadas por ese parámetro t tal que (x=f(t), y=g(t) ).Por ejemplo graficamos el lugar geométrico de todos los puntos  (t^2,t) tendremos que la sintaxis será clara,                 plot([x(t), y(t), t=rango de t], h, v, opciones) los dos primeros elementos de la lista del argumento seran x, y, variación del parámetro

>	plot([t^2, t, t = -1..1]);

igualemente

>	plot([sin(t^2), t, t = -2*Pi..2*Pi]);

En Física cuando graficamos la velocidad vs la posición llamamos a ese espacio el espacio de fases. Así para un oscilador armónico simple tendremos

>	omega0:=2*Pi/5: xosc(t):= 2*sin(omega0*t); plot( [xosc(t), diff(xosc(t),t), t = -5..5], labels=[`Posicion`,`Velocidad`],labeldirections = [horizontal, vertical]);

Quizá el  ejemplo, más emblemático de representación paramétrica de una curva lo constituye la circunsferencia centrada en el origen que viene dada por el lugar geométrico, coordenadas cartesianas, de los puntos (x,y) -> , entonces pod

>	radio1 := 5: plot([radio1*cos(t), radio1*sin(t), t = 0..2*Pi], scaling = CONSTRAINED);

Polares

Una gráfica en coordenadas polares viene dada por la representación de  Si consideramos un radio constante y graficamos su trayectoria variando el ángulo  describimos una circunsferencia centrada en el origen. Es equivalente a graficar una curva paramétrica del lugar geométrico del tipo (x= , y= ) y se varía el parámetro  obviamente le indicamos a MAPLE que la gráfica viene en coordenadas plares. Si graficamos la misma circunsferencia centrada en el origen del punto anterior tendremos:

>	radio2 :=5; plot([radio2 , theta, theta=0..2*Pi],coords=polar);

si por el contrario  entonces

>	plot([sin(theta) , theta, theta=0..2*Pi],coords=polar, scaling=constrained);

En la Aproximación de Born para dispersión elástica de electrones que inciden sobre átomos, se obtiene la expresión para la sección eficaz diferencial para el scatering apantallado de Rutherford.

>	sigma1:=(k,theta)->(1/4)*( (Z^2*(1-(1/(1+4*k^2*a^2*sin(theta/2)^2)^2))^2)/(k^4*sin(theta/2)^4));

en la cual  es la energía de dispersión que se considera fija; Z  es el número atómico y a corresponde con el factor de apantallamiento. Si graficamos la sección eficaz diferencial respecto al ángulo, nos queda algo como

>	plot(subs(a=1/2,Z=1,sigma1(1,theta)), theta=0..2*Pi, labels=["theta","sigma"]);

es mucho más intuitiva si realizamos la gráfica en coordenadas polares.

>	plot([subs(a=1/2,Z=1,sigma1(1,theta)), theta, theta=0..2*Pi], coords= polar,scaling=constrained);

Es mucho más evidente el patrón de dispersión el valor de la función para cada ángulo. Algo parecido presenta R. Landau en el patrón de dispersión de Rayos x de baja energía dispersados por una esfera

>	sigma:=3+2*cos(theta)^4 + 2*cos(theta); plot(sigma, theta=0..2*Pi, labels=["theta","sigma"], scaling=constrained);

no es obvia la forma del patrón de dispersión cosa que es clara cuando se grafica en término de coordenadas polares

>	plot([sigma, theta, theta=0..2*Pi],coords=polar,scaling=constrained);

Cambio de opciones por  omisión

Lo primero que exploramos en el uso de los nuevos comandos que provee el paquete plots es la posibilidad de crear un conjunto, personalizado de opciones por omisión. Así las opciones por omisión pueden ser alteradas mediante

>	setoptions(scaling = CONSTRAINED);

Opción que será supuesta por omisión a partir de este momento y la cual pude ser revertida mediante:

setoptions(scaling = UNCONSTRAINED);

Gráficas Logarítmicas

Seguidamente exploraremos otra de las opciones de plots que permite realizar gráficas logarítmicas, mediante los comandos logplot (eje vertical logarítmico), semilogplot (eje horizontal logarítmico) loglogplot (ambos ejes logarítmicos)

Así tendremos que

>	semilogplot([ln(3*x)/10,log[10](x)], x=1..2*Pi, labels=["log10(x)","y"],labeldirections = [horizontal, vertical],legend = ["ln(3*x)/10","log[10](x)"], title="Grafica Semi log = eje x log");

>	logplot([ln(3*x)/10,log[10](x)], x=1..2*Pi, labels=["x","log10(y)"],labeldirections = [horizontal, vertical],legend = ["cos(x) + sen(x)","log[10](x)"], title="Grafica Semi log = eje y log",numpoints=500);

Nótese como hemos aumentado el número de puntos de graficación a través de la opción numpoints=500

>	loglogplot([ln(3*x)/10,log[10](x)], x=1..2*Pi, labels=["log10(x)","log10(y)"],labeldirections = [horizontal, vertical],legend = ["cos(x) + sen(x)","log[10](x)"], title="Grafica Semi log = ejes x y log",numpoints=500 );

>

Otra vez, varias Gráficas en una: la función display

Otra forma de representar varias curvas en una sola gráfica es a través de la función display del paquete plots. Esta función permite mostrar varias gráficas mediante la asignación de gráficas a variables, para luego "mostrar" el conjunto de variables. Así el ejemplo más trivial lo constituye las g[raficas del seno y el conseno. Esto es

>	S := plot(sin):  C := plot(cos): display({S,C}, title = "Seno y Coseno");

Un ejemplo más interesante lo constituye el movimiento bajo fuerzas centrales cuando consideramos un potencial del tipo  el cual es típico en el movimiento planetario o en movimentos bajo fuerzas coulombinas. Es claro que  para el caso de gravitación universal newtoniana o  para el caso de las fuerzas coulombianas. Para este caso la trayectoria de los cuerpos sometidos a la acción de la fuerza que deriva del potencial será

>	r1:=(theta)->lambda*(1+epsilon)/(1+epsilon*cos(theta-theta0));

donde  y   , la excentricidad, viene dado por    Con L la cantidad de movimiento angular; E la energía total. Nóteses que   será positivo, para potenciales atractivos ( > 0 ) y será negativo para potenciales repulsivos ( < 0). Igualmente recordemos que la esta evolución corresponde a una representacion de secciones cónicas y las cuales se ilustran

>

theta0:=0; rElipse := subs (lambda=1,epsilon=1/2,r1(theta)): rParabola := subs (lambda=1,epsilon=1,r1(theta)): rHiperbolaP := subs (lambda=1,epsilon=2,r1(theta)): rHiperbolaN := subs (lambda=-1,epsilon=2,r1(theta)): grfrElipse:=plot([rElipse,theta,theta=0..2*Pi],coords=polar, color=red): grfrParabola:=plot([rParabola,theta,theta=0..2*Pi],coords=polar, color =green ): grfrHiperbolaP:=plot([rHiperbolaP,theta,theta=0..2*Pi],coords=polar, color =blue ): grfrHiperbolaN:=plot([rHiperbolaN,theta,theta=0..2*Pi],coords=polar,color =yellow): display([grfrElipse,grfrParabola,grfrHiperbolaP,grfrHiperbolaN], view=[-10..1,-10..10], title="Secciones Cónicas");

Explorando el comportamiento de datos con animaciones.

Existen dos formas de representar animaciones con MAPLE: una limitada utilizando el comando animate y otra forma utilzando el

comando display  analicemos ambos casos

Campos y Contornos

Para ejemplificar una de las mejoras con el uso de las extensiones de plots supongamos dos lineas con cargas opuestas e infinitas, situadas perpendiculares al plano x,y que lo atraviezan en las posiciones (-1,0,0) y (1,0,0) el potencial electrostático vendrá dado por

>	phi := ln(sqrt((x+1)^2)+y^2) -ln(sqrt((x-1)^2)+y^2);

una gráfica que muestra la intensidad de estas líneas de potencial surge de

>	gradplot(-phi,x=-2..2, y=-2..2,arrows=thick, grid=[11,11], axes=box);

Del mismo modo tendremos como gráficos de contorno

>	contourplot(phi, x=-2..2, y=-2..2,axes=box);

con más puntos y mas contornos es mucho más clara

>	contourplot(phi, x=-2..2, y=-2..2, numpoints=1000, contours=20);

Pero aún se puede trabajar un poco más

>	contourplot(phi, x=-2..2, y=-2..2, numpoints=1000, contours=20,                 filled=true, coloring=[white,black] );

y si las hacemos en 3D, tendremos

>	implicitplot3d(z=phi, x=-2..2, y=-2..2, z= -3..3);

>	implicitplot3d(z=phi, x=-2..2, y=-2..2, z= -3..3, numpoints=5000); # con muchos más puntos

Pero podemos ir más allá y exportar estas gráficas a un formato vrml (virtual reality markup language) el cual es posible explorarlo con cualquier navegador

>	grfcargas:=implicitplot3d(z=phi, x=-2..2, y=-2..2, z= -3..3,numpoints=500): # asigno la grafica a una variable vrml( grfcargas, `c:/Luisn/Latex/cursos/visualizacion/cargas.wrl`):

Curvas en el espacio

El paquete plots  permite dibujar curvas en el espacio. El comando no puede ser más intuitivo plots[spacecurve]. Por su parte la sintaxis del comando es escencialmente la misma que las curvas paramétricas definidas en 2D. En general representaremos una curva en el espacio parametrizada por una variable esto es

y también podemos representarla mediante puntos que serán unidos

(( ), ( ), ... ).

por segmentos de rectas. Así, la curva paramétrica de una hélice circular en el espacio queda representada por

>	spacecurve([cos(t), sin(t), t, t=0..2*Pi], colour = BLACK, axes = NORMAL);

y nudos en el espacio

>	knot:= [ -10*cos(t) - 2*cos(5*t) + 15*sin(2*t),         -15*cos(2*t) + 10*sin(t) - 2*sin(5*t), 10*cos(3*t), t= 0..2*Pi]: spacecurve(knot,axes=framed);

Funciones implícitas con implicitplot3d

Tal y como vimos antes, se pueden graficar superficies con la utilización de a biblioteca plots la sintaxis del comando es

implicitplot3d(expr, x=a..b, y=c..d, z=p..q, opciones)

Nótese a continuación que la opción grid = [k, l, m] indica que la malla de la superfice es k x l x m . La opción por omisión es 10 x 10 x 10.

De esta forma tenemos

>	restart;with(plots):implicitplot3d(x^3+y^3+z^3+1=(x+y+z+1)^3, x=-2..2, y=-2..2, z=-2..2, grid=[15,15,15]);

Warning, the name changecoords has been redefined

y en distintos sistemas de coordenadas

>	implicitplot3d(r=(1.3)^x*sin(y), r=0.1..5, x=-1..2*Pi, y=0..Pi, coords=spherical);

y utilizando listas o conjuntos para superponer gráficas

>	implicitplot3d([(x+2)^2+(y+2)^2+(z+2)^2=9, (x-2)^2+(y-2)^2+(z-2)^2=6], x=-5..5, y=-5..5, z=-5..5, color=[blue,green], scaling=constrained, axes=boxed);

>

Graficando Funciones Complejas con

Funciones de variable compleja f(z) = f(x + i y) = ( re f, im f), pueden graficadas utilizando el comando

complexplot3d(f(z), z=a + b*I..c + d*I) y el rango de "variación" de z viene dado por a + b*I..c + d*I

Esto puede verse como

>	complexplot3d( sec(z) , z = -2 - 2*I .. 2 + 2*I,axes=framed );

juegue con los botones, note los ejes y compruebe la forma como se grafica funciones complejas.

>